Paraboles en seconde

Discussion sur l'enseignement de l'algorithmique avec Xcas au lycee
alb
Messages : 1320
Inscription : ven. août 28, 2009 3:34 pm

Paraboles en seconde

Message par alb » ven. nov. 12, 2010 7:15 pm

Un petit programme qu'il est facile d'élaborer avec des élèves de seconde pour les faire travailler sur les paraboles.

Code : Tout sélectionner

Parabole(a,b,c):={
  local E,absc,ordo,axe,leg,seg;
  E:=a*x^2+b*x+c;
  //le graphe de E est-il toujours une parabole ?
  si a==0 alors retourne "la courbe n'est pas une parabole";fsi;
  //la fonction admet-elle un minimum, un maximum ?
  si a>0 alors absc:=fMin(E);sinon absc:=fMax(E);fsi;
  ordo:=subst(E,x=absc);
  //Quelle est l'équation de l'axe de symétrie ?
  axe:=droite(x=-b/2a,affichage=ligne_tiret+rouge);
  leg:=legende(point(absc,0),absc,quadrant4),
    legende(point(0,ordo),ordo,quadrant2);
  seg:=segment(point(absc,ordo),point(0,ordo),affichage=ligne_tiret);
  retourne axe,leg,seg,graphe(E,x=-b/2a-5..-b/2a+5,affichage=epaisseur_ligne_2);
}
:;
Inter2paraboles(a1,b1,c1,a2,b2,c2,opt):={
//opt=1 pour les abscisses des points d'intersection
//opt=0 pour les deux graphes
  local E1,E2;
  si opt==1 alors
    E1:=a1*x^2+b1*x+c1;E2:=a2*x^2+b2*x+c2;
    retourne solve(E1=E2);
  sinon
    retourne Parabole(a1,b1,c1),Parabole(a2,b2,c2);
  fsi;
}
:;
On peut faire Inter2paraboles(2,8,-3,-3,6,21,0) pour avoir le graphique et changer 0 en 1 pour avoir la liste des abscisses des points d'intersection.
On peut dans une fenêtre de géométrie définir un paramètre m puis faire Parabole(m,2,-3) pour montrer le lien entre le signe de m et la convexité.

alb
Messages : 1320
Inscription : ven. août 28, 2009 3:34 pm

Re: Paraboles en seconde

Message par alb » dim. nov. 21, 2010 1:51 pm

C'est énervant à la fin tous ces manuels qui ne conjecturent qu'avec Geogebra.
Un exemple parmi d'autres:
Il s'agit de trouver a et c pour que la parabole d'équation y=a*x^2-8*a*x+c passe par le point A(0,4),départ du tir, et le point B(10,0),position de la cible,tout en respectant une altitude inférieure à 8.
NB: unité=100 mètres.
Voici un script qu'il suffit de coller en Geo2d:

Code : Tout sélectionner

A:=point(0,4);B:=point(10,0);
a:=element((-5) .. 5,-0.15,0.01);
c:=element(0 .. 8,5.8,0.01);
E:=exact(a*x^2-8*a*x+c);
graphe(E,x=-5..15);
si subst(E,x=0)==4 alors  "A est sur la parabole" sinon  "A n'est pas sur la parabole" fsi;
si subst(E,x=10)==0 alors  "B est sur la parabole" sinon  "B n'est pas sur la parabole" fsi;
si subst(E,x=fMax(E))<8 alors "le tir est sécurisé" sinon "le tir n'est pas sécurisé" fsi;
Triple avantage:
on peut conjecturer,
c'est une démonstration,
parabole et algorithmique dans le même exercice.

Répondre